Strukturalna obsługa błędów w ABL cz. II

W poprzednim odcinku obiecałem napisać o tym jak utworzyć własną klasę obsługi błędów oraz pokazać, że strukturalną obsługę błędów można stosować także w przypadku procedur uruchamianych na serwerze aplikacji. Obie te kwestie pokażę na jednym przykładzie.

W Developer’s Studio klasę definiujemy najwygodniej przy pomocy wizarda, tak jak każda inną klasę. Musimy pamiętać, że dziedziczy ona z klasy Progress.Lang.AppError oraz że trzeba zdefiniować ją jako Serializable, co oznacza, że instancja klasy może być przekazywane przez wartość pomiędzy sesjami AVM (ABL Virtual Machine).

Poniżej widzimy gotową klasę Errors.myError zawierającą właściwości: Errormessage, ErrorNum oraz ProcName oraz dwie metody GetErrorMessage() i GetVerboseErrorMessage(). Posłużą one do własnej obsługi błędów.
Pierwsza metoda zwraca jedynie komunikat wraz z numerem błędu. GetVerboseErrorMessage() zawiera także nazwę procedury, w której ten błąd wystąpił. Gdybyśmy tworzyli program złożony z obiektów moglibyśmy użyć nazwy klasy i metody aby mieć więcej informacji o lokalizacji wystąpienia błędu itp.

USING Progress.Lang.*.
USING Progress.Lang.AppError.

BLOCK-LEVEL ON ERROR UNDO, THROW.

CLASS Errors.myError INHERITS AppError SERIALIZABLE: 

    DEFINE PUBLIC PROPERTY ErrorMessage AS CHARACTER NO-UNDO 
    GET.
    SET. 

    DEFINE PUBLIC PROPERTY ErrorNum AS INTEGER NO-UNDO 
    GET.
    SET. 
    
    DEFINE PUBLIC PROPERTY ProcName AS CHARACTER NO-UNDO 
    GET.
    SET. 

    CONSTRUCTOR PUBLIC myError (
        INPUT pErrorNum AS INTEGER,
        INPUT pErrorMessage AS CHARACTER,
        INPUT pProcName AS CHARACTER):            
        SUPER ().
        ErrorNum = pErrorNum.            
        ErrorMessage = pErrorMessage.
        ProcName = pProcName.
    END CONSTRUCTOR.

    METHOD PUBLIC CHARACTER GetErrorMessage(  ):
        DEFINE VARIABLE res AS CHARACTER NO-UNDO.
        res =  ErrorMessage + ". " + STRING(ErrorNum).
        RETURN res.
    END METHOD.

    METHOD PUBLIC CHARACTER GetVerboseErrorMessage(  ):
        DEFINE VARIABLE res AS CHARACTER NO-UNDO.
        res =  ErrorMessage + ". " + STRING(ErrorNum) + ". Proc: " + ProcName.
        RETURN res.
    END METHOD.    
    
END CLASS.  

Poniższy przykład jest analogiczny do tego z poprzedniego odcinka – został zmodyfikowany do uruchomienia na serwerze aplikacji, oczywiście z własną obsługą błędów.

USING Errors.myError.

VAR INT i = 1.
DEFINE VARIABLE hServer AS HANDLE NO-UNDO.
DEFINE VARIABLE lReturn AS LOGICAL NO-UNDO.

CREATE SERVER hServer.
lReturn = hServer:CONNECT("-URL http://localhost:8810/apsv
  -sessionModel Session-managed"). 

IF NOT lReturn THEN DO:
  DELETE OBJECT hServer NO-ERROR.
  RETURN ERROR "Failed to connect to the ABL web application: " + RETURN-VALUE.
END.

RUN catcherror-pasoe-myerror.p ON hServer (INPUT 3000).

CATCH myerr AS MyError:
    MESSAGE myerr:GetVerboseErrorMessage()
        VIEW-AS ALERT-BOX INFO BUTTONS OK.
END.
/************************************************************/

/* catcherror-pasoe-myerror.p */
BLOCK-LEVEL ON ERROR UNDO, THROW.

USING Errors.myError.

DEFINE INPUT PARAMETER icustNum AS integer.
DEFINE VARIABLE ProcName AS CHARACTER.


FIND customer WHERE customer.custnum = icustNum.
if country NE "Poland" THEN DO:
    ProcName = ENTRY(1, PROGRAM-NAME(1),' ').
    UNDO, THROW NEW myError(555, "Bad country", ProcName).

END. 

Ponieważ użyłem metody GetVerboseErrorMessage() otrzymuję cały komunikat z nazwą procedury w której wystąpił błąd.

Strukturalna obsługa błędów w ABL cz. I

Zanim przejdziemy do omówienia strukturalnej obsługi błędów w języku ABL, trzeba przypomnieć pewne (oczywiste) fakty dotyczące tego języka.

ABL (wcześniej 4GL) był zawsze proceduralnym językiem bazodanowym o strukturze blokowej. Umożliwia on łączenie logiki biznesowej i interfejsu użytkownika w jednym pliku procedury zawierającym instrukcje, blok główny i bloki zagnieżdżone. Blokowa struktura jest tu niezwykle istotna, ponieważ z nią związane są zakresy transakcji, blokady rekordów a także obsługa błędów.

Od samego początku obsługa błędów (nazywana tradycyjną) była zaimplementowana w języku 4GL. Związane są z nią takie słowa kluczowe jak NO-ERROR, STATUS-ERROR, RETURN ERROR, bloki typu ON ERROR itd. Programiści dobrze wiedzą o co chodzi.

W wersji OpenEdge 10 język 4GL wyewoluował do ABL, zawierając oprócz poprzednich instrukcji także technologię programowania obiektowego i razem z tymi zmianami pojawiła się strukturalna obsługa błędów. Jest to model obsługi błędów spotykany w wielu językach, ale zazwyczaj jest kojarzony z językami obiektowymi i składnią typu: try i catch.

Instrukcja try umożliwia zdefiniowanie bloku kodu, z którym można powiązać zachowanie związane z obsługą błędów. Z kolei instrukcja catch służy do zdefiniowania obsługi błędu i powiązanie jej z typem błędu. Gdy system wykryje błąd w bloku try, wykona kod w bloku catch, który pasuje do błędu. Jeśli takiego bloku nie ma, to obsługa błędu jest przekazywana najczęściej w dół stosu wywołań, dopóki system nie znajdzie odpowiedniego bloku catch.

Strukturalna obsługa błędów posiada następujące cechy:

  • Wszystkie błędy są reprezentowane w postaci obiektów
  • Można zdefiniować własne typy błędów (klasy)
  • Można wywołać (throw) błąd explicite
  • Można obsłużyć (catch) określone typów błędów w określonym bloku ABL.
  • Możliwość propagacji błędu (ponowny throw).
  • Jeśli chodzi o implementację tej technologii w języku ABL, to należy przypomnieć, że jest to język o strukturze blokowej, gdzie prawie wszystkie bloki są blokami transakcyjnymi UNDO (poza zwykłym blokiem grupującym DO:…END.) i nie ma potrzeby budowania specjalnych bloków try, co ułatwia programowanie.

    OK, napiszmy pierwszy prosty przykład własnej obsługi błędu, korzystając z faktu, że w tablicy Customer nie ma rekordu o polu CustNum = 1000.

    DO ON ERROR UNDO, LEAVE:
        FIND FIRST Customer WHERE CustNum = 1000.
        MESSAGE Customer.Name VIEW-AS ALERT-BOX.
        CATCH mySysError AS Progress.Lang.SysError:
            MESSAGE mySysError:GetMessage(1) VIEW-AS ALERT-BOX ERROR.
        END CATCH.
    END.
    

    Wykorzystaliśmy tutaj blok transakcyjny DO ON ERROR UNDO,… W przypadku gdy rekord nie będzie odnaleziony zostanie “wyłapany” błąd systemowy i obsłużony przez nas w bloku CATCH:…END. Blok ten musi być na końcu bloku transakcyjnego. Taki “złapany” błąd przestaje istnieć w sesji ale co jeśli chcemy go przekazać po obsłużeniu do zewnętrznego bloku (np. bloku procedury)? Wystarczy następująca modyfikacja:

    DO ON ERROR UNDO, LEAVE:
        FIND FIRST Customer WHERE CustNum = 1000.
        MESSAGE Customer.Name VIEW-AS ALERT-BOX.
        CATCH mySysError AS Progress.Lang.SysError:
            MESSAGE mySysError:GetMessage(1) VIEW-AS ALERT-BOX ERROR.
            UNDO, THROW mySysError.
        END CATCH.
    END.
    
    CATCH mySysError AS Progress.Lang.SysError:
        MESSAGE mySysError:GetMessage(1) VIEW-AS ALERT-BOX.
    END CATCH.
    

    Teraz możemy wychwycić go i obsłużyć ponownie.
    Należy dodać, że jeśli użyjemy tradycyjnej składni obsługi błędu NO-ERROR, to ma ona pierwszeństwo nad obsługą strukturalną. W poniższym przykładzie blok CATCH nie będzie więc wywołany.

    DO ON ERROR UNDO, LEAVE:
        FIND FIRST Customer WHERE CustNum = 1000 NO-ERROR.
        IF AVAILABLE (Customer) THEN 
           MESSAGE Customer.Name VIEW-AS ALERT-BOX.
        CATCH mySysError AS Progress.Lang.SysError:
            MESSAGE mySysError:GetMessage(1) VIEW-AS ALERT-BOX ERROR.
            UNDO, THROW mySysError.
        END CATCH. 
    END.
    

    Poniżej przedstawiłem uproszczony schemat dziedziczenia klas. Progress.Lang.Error służy do wychwycenia dowolnego błędu. Progress.Lang.ProError służy do wychwycenia dowolnego rodzaju błędu Progress: systemu, aplikacji, SOAP. Progress.Lang.SysError służy do wychwycenia błędów języka ABL, np.: niepowodzenie instrukcji FIND, błąd indeksu; wszystko, co obsługuje NO-ERROR. Progress.Lang.AppError służy do wychwycenia błędów aplikacji zgłaszanych (throw) zgodnie z regułami biznesowymi ABL. Z tej klasy może dziedziczyć nasza własna klasa do obsługi błędów.

    Zobaczmy teraz jak wychwytywać błędy w procedurach i przesyłać stosowne komunikaty do programu głównego.
    W tradycyjnej obsłudze błędów mogliśmy skorzystać ze składni w programie wywołującym: IF ERROR-STATUS:ERROR THEN MESSAGE RETURN-VALUE VIEW-AS ALERT-BOX ERROR.
    oraz w wywoływanym RETURN ERROR “Brak rekordu w bazie”.

    W obsłudze strukturalnej mamy szersze pole do popisu. Przyjrzyjmy się poniższemu przykładowi.

    /* main.p */
    VAR INT i = 1.
    
    RUN FindCustomer.p (1000).
    
    CATCH syserr AS Progress.Lang.SysError:
        MESSAGE "Customer: " syserr:GetMessage(1)
           VIEW-AS ALERT-BOX INFO BUTTONS OK.
    END.
      
    CATCH apperr AS Progress.Lang.AppError:
      DO WHILE i <= apperr:NumMessages:
          MESSAGE "Country: " apperr:GetMessage(i)  
                              apperr:GetMessageNum(i)
             VIEW-AS ALERT-BOX INFO BUTTONS OK.
          i = i + 1.    
      END.      
    END.
    
    /************************************************************/
    
    /* FindCustomer.p */
    BLOCK-LEVEL ON ERROR UNDO, THROW.
    
    DEFINE INPUT PARAMETER icustNum AS integer.
    
    FIND customer WHERE customer.custnum = icustNum.
    IF country NE "Poland" THEN
        UNDO, THROW NEW Progress.Lang.AppError("Niewłaściwy kraj", 555).
        
    /* Można dodac więcej komunikatów własnej obsługi błędów */    
    CATCH e AS Progress.Lang.AppError :
        e:AddMessage("Klient nie jest z Polski", 777).
        undo, throw e.     
    END CATCH.
    

    Na początku wywoływanej procedury FindCustomer.p znajduje się instrukcja BLOCK-LEVEL ON ERROR UNDO, THROW. która gwarantuje, że wszystkie nieobsługiwane błędy w blokach transakcyjnych, zostaną propagowane do obiektu wywołującego. Jeśli wywołamy tę procedurę z parametrem 1000 (a więc będzie brak rekordu Customer) błąd zostanie obsłużony w procedurze main.p w bloku CATCH syserr AS Progress.Lang.SysError (ponieważ będzie to błąd systemowy).
    Załużmy, że jeśli rekord zostanie znaleziony, będziemy chcieli sprawdzić czy na pewno klient jest z Polski a jeśli nie, to ustawić własny błąd. Definiujemy więc błąd typu AppError: ...THROW NEW Progress.Lang.AppError("Niewłaściwy kraj", 555).
    Po pewnym czasie chcielibyśmy dodać jeszcze jeden komunikat dla tego błędu. Możemy to zrobić bez problemu gdyż ta klasa posiada metodę AddMessage jak widać poniżej w Class Browser w Developer's Studio (dla klasy SysError nie ma takiej możliwości).

    Możliwości obsługi błędów w aplikacjach ABL jest więc całkiem sporo. Wiem, że niektórzy chcieliby wiedzieć jak poradzić sobie z serwerem aplikacji i czy można pisać własne klasy obsługi, ale o tym następnym razem.

    Testy ABLUnit

    Testowanie jest nieodłącznym elementem budowania aplikacji. Istnieją różne metody, które mają dać pewność deweloperom, że aplikacja poradzi sobie w każdej sytuacji, bez względu na podawane dane a interfejs będzie tzw. “idiotoodporny”. My skupimy się tutaj tylko na pierwszej części czyli logice aplikacji. I znowu, ten element można testować na różne sposoby np. wykorzystując debugger, kompilację kodu z opcją XREF, czy komunikaty zrzucające dane do plików na dysku. Jednakże te metody mają wadę, polegającą na testowaniu jednej sytuacji na raz, a my chcielibyśmy zautomatyzować testowanie dla różnych sytuacji i różnych wprowadzanych danych.
    Do tego celu bardzo dobrze nadaje się testowanie tzw. ABLUnit, dla którego w Developer’s Studio jest zdefiniowany specjalny typ projektu. Testy te zostały wprowadzone od wersji OpenEdge 11.4 i mają zastosowanie dla kodu ABL zarówno do procedur jak i klas.

    Na początku musimy przyswoić sobie pewne pojęcia związane z testowaniem.

    Przypadek testowy (test case) odnosi się do pliku procedury ABL lub pliku klasy. Przypadek testowy może zawierać wiele testów (zestaw testów).

    Test to wewnętrzna procedura w pliku procedury lub metoda w pliku klasy, oznaczona adnotacją @Test.

    Asercje (assertions) – służą do określenia, czy dany test powiódł się czy nie. ABLUnit zapewnia metody asercji dla wszystkich typów danych ABL. Sukces lub niepowodzenie tych twierdzeń jest śledzone przez platformę i można je wyświetlić po zakończeniu przebiegu testu.

    Zestaw testów (test suite) to zbiór przypadków testowych. Służy on do organizowania i uruchamiania przypadków testowych w grupach logicznych. Zestaw testów może zawierać dowolną liczbę przypadków testowych.

    Poniższy obrazek przedstawia cykl wykonania ABLUnit.

    Jak wspomniałem wcześniej, każdy test powinien być opatrzony adnotacją @Test. Testowana procedura lub klasa może mieć dowolną liczbę testów, a każdy test jeden zestaw metod/procedur, które są opatrzone adnotacjami @Setup i @TearDown. Przypadek testowy (test case) może mieć po jednej metodzie/procedurze oznaczonej adnotacjami @Before i @After. @Before jest wykonywana raz przed rozpoczęciem testów i może być wykorzystana np. do podłączenia się do bazy. @After jest natomiast wykonywana po ukończeniu testów i może być wykorzystana np. do odłączenia bazy.
    Proces testowania rozpoczniemy od stworzenia projektu typu OpenEdge ABLUnit.

    Projekt ten jest podłączony do bazy sports2000. Dodajemy do niej tabelę login, która ma dwa pola: username i password (patrz słownik baz danych poniżej).

    W tabeli login wstawiamy jeden rekord o polach jak poniżej. Będzie on reprezentować prawidłowe dane logowania do aplikacji.

    create login.
    username = "test".
    password = "test".
    

    Plik Main.p to nasz testowany moduł aplikacji. Zawiera on prosty kod sprawdzający czy osoba logująca się podała prawidłowe dane, dane nieprawidłowe lub nie podała żadnych danych.
    W drugim i trzecim przypadku generowany jest błąd z odpowiednim komunikatem.

    /* Main.p */
    USING Progress.Lang.AppError FROM PROPATH.
    DEFINE VARIABLE mye AS Progress.Lang.AppError NO-UNDO.
    
    PROCEDURE loginProc :
      DEFINE INPUT PARAMETER username AS CHARACTER.
      DEFINE INPUT PARAMETER password AS CHARACTER.
      DEFINE OUTPUT PARAMETER loginResult AS CHARACTER INIT "Fail".
      IF username EQ ? THEN
        DO:
          mye = NEW Progress.Lang.AppError("Username is empty", 200).
          mye:ReturnValue = "Username cannot be empty".
          RETURN ERROR mye.
        END.
    
      FOR EACH login WHERE login.username = username:
        IF login.password = password THEN
        loginResult = "Success".
        ELSE DO:
          mye = NEW Progress.Lang.AppError("wrong password", 200).
          mye:ReturnValue = "Password is wrong". 
          RETURN ERROR mye.
        END.    
      END.
    END PROCEDURE.
    

    Aby uruchomić powyższą procedurę z naszych testów, należy:

  • Połączyć się z bazą danych (@Before).
  • Uruchomić główną procedurę (main.p), używając wskaźnika w trybie PERSISTENT (@Setup).
  • Podać wartości wejściowe (@Test).
  • Uruchomić wewnętrzną procedurę loginProc z parametrami wejściowymi i wyjściowymi (@Test).
  • Sprawdzić wynik testu poprzez asercję (@Test).
  • Usunąć procedurę z pamięci (@TearDown).
  • Odłączyć się od bazy danych (@After).
  • Poniżej znajduje się procedura do przeprowadzenia testów (TestCase.p).

    /* TestCase.p */
    USING OpenEdge.Core.Assert FROM PROPATH.
    
    BLOCK-LEVEL ON ERROR UNDO, THROW.
    
    DEFINE VARIABLE procHandle AS HANDLE NO-UNDO.
    DEFINE VARIABLE uname AS CHARACTER NO-UNDO.
    DEFINE VARIABLE pwd AS CHARACTER NO-UNDO.
    DEFINE VARIABLE res AS CHARACTER NO-UNDO.
    
    @Before.
    PROCEDURE Before:
    CONNECT C:\WrkOpenEdge126\db\sports2000.db -H localhost -S 10005 NO-ERROR.
    END PROCEDURE.
    
    @Setup.
    PROCEDURE setUp:
    RUN main.p PERSISTENT SET prochandle.
    END PROCEDURE.
    
    @Test.
    PROCEDURE validusr: /* Test1 */
    uname = "test".
    pwd = "test".
    RUN loginProc IN procHandle (INPUT uname,INPUT pwd,OUTPUT res) .
    Assert:equals("success", res).
    END PROCEDURE.
    
    @Test.
    PROCEDURE invalidusr1: /* Test2 */
    uname = "ablunit".
    pwd = "test".
    RUN loginProc IN procHandle (INPUT uname,INPUT pwd,OUTPUT res) .
    Assert:equals("success", res).
    END PROCEDURE.
    
    @Test.
    PROCEDURE emptyUsr: /* Test3 */
    uname = ?.
    pwd = "invalid".
    RUN loginProc IN procHandle (INPUT uname,INPUT pwd,OUTPUT res) .
    Assert:equals("success", res).
    END PROCEDURE.
    
    @TearDown.
    PROCEDURE tearDown:
    DELETE PROCEDURE procHandle.
    END PROCEDURE.
    
    @After.
    PROCEDURE tearDownAfterProcedure:
    DISCONNECT sports2000.
    DELETE PROCEDURE THIS-PROCEDURE.
    END PROCEDURE.
    

    Po uruchomieniu procedury TestCase.p pojawi sie plik results.xml.

    Klikamy na niego dwukrotnie a w oknie konsoli, w zakładce ABLUnit pojawią się wyniki naszych testów.

    Zgodnie z naszymi przewidywaniami tylko pierwszy test zakończył się powodzeniem.
    Zachęcam do własnych testów!

    Debugging w aplikacjach PASOE

    W kilkunastu postach opisywałem tworzenie serwisów i aplikacji z udziałem serwera aplikacji PASOE i coraz więcej naszych klientów korzysta z tej technologii. Coraz częściej powtarza się pytanie: jak można wykorzystać debugger aby wychwytywać błędy i testować aplikacje.
    PASOE to połączenie technologii Tomcat (Java) i OpenEdge (ABL), więc kompletny proces debuggowania jest dość złożony.
    Tutaj chciałbym pokazać jak zacząć ten proces z punktu widzenia OpenEdge’a.

    Jak zwykle przed przystąpieniem do wykorzystania debuggera, trzeba włączyć tę funkcjonalność w środowisku OpenEdge. Należy uruchomić komendę prodebugenable -enable-all jako administrator.

    Drugim krokiem jest wdrożenie web aplikacji oedb.war w testowanej instancji. Pamiętajmy, że ze względów bezpieczeństwa, nigdy nie wdrażać jej w środowisku produkcyjnym!
    pasman deploy -I oepas1 %DLC%\servers\pasoe\extras\oedbg.war


    Cały proces debuggowania będzie odbywał się w Progress Developer’s Studio for OpenEdge.
    Wykorzystam do testowania plik klasy wygenerowany przy tworzeniu prostego serwisu REST i dodania zasobu (Business Entity) Customer, co opisywałem na początku 2016 roku.
    Dostajemy klasę customer.cls z metodami CRUD: CreateCustomer, ReadCustomer, UpdateCustomer i DeleteCustomer. Ja wykorzystam metodę ReadCustomer i wstawię breakpoint zaraz za instrukcją SUPER:ReadData(filter). klikając po lewej stronie dwukrotnie myszką.

    Teraz klikając prawym przyciskiem myszy na instancję PASOE wybieramy Restart in Debug.


    Następnie uruchamiamy serwis w przeglądarce poprzez link dla Custnum=1,
    http://localhost:8810/CustProj/rest/CustProjService/customer?filter=Custnum=1
    a w następnej kolejności dla Custnum < 5.
    http://localhost:8810/CustProj/rest/CustProjService/customer?filter=Custnum<5

    W PDSOE w widoku dla zmiennych zobaczymy wartość filtra odpowiednio “Custnum=1″oraz “Custnum<5”.
    Widać z tego, że zasada testowania aplikacji przy pomocy debuggera jest dość prosta.



    Dodam jeszcze jedną informację, ponieważ byłem o to kilka razy pytany: W sytuacji gdy mamy wiele projektów i instancji PASOE, jak sprawdzić która instancja obsługuje dany serwis.
    Można sprawdzić np. poleceniem tcman jakie serwisy są wdrożone w danej instancji, a w PDSOE podejrzeć właściwości danego projektu jak na widoku poniżej.

    Cały proces debuggowania można prześledzić na kanale Youtube.
    Webinar ten jest rozszerzony o testowanie aplikacji nie tylko lokalnych ale także zdalnych.

    OpenEdge 12.7

    5 maja pojawiła się wersja OpenEdge 12.7. Ma być ona ostatnią z wersji Innovation dla dwunastki ponieważ ostatnia, zapowiadana na koniec roku, ma być wersją LTS. Przyjrzyjmy się wybranym nowościom.

    PROSTRCT REMOVEONLINE – nowa komanda poprawiająca dostępność bazy danych. Umożliwia usuwanie extentów lub całych obszarów bez konieczności zamykania bazy.

    PROUTIL TABLEREORG to narzędzie służące do poprawy stopnia fragmentacji w tabelach (zastępuje operacje dump i load online) dla obszarów typu II. Wprowadzono je w OE 12.3, a teraz dodano nowe parametry np. restrict czy nosmartscan. Pierwsza opcja jest przeznaczona dla dużych tabel i pozwala na reorganizację wybranego fragmentu tabeli wg. wartości pola. Druga opcja wyłącza domyślne inteligentne skanowanie. Przykład poniżej.

    Wprowadzono nowy typ pakietu (lub biblioteki) kodu aplikacji ABL, który można podpisać i weryfikować, aby mieć pewność, że skompilowany kod aplikacji ABL nie został uszkodzony ani zmodyfikowany. Ten nowy typ biblioteki jest znany jako plik archiwum i ma rozszerzenie .apl. Do utworzenia archiwum, dodawania r-kodów służy komenda PROPACK, a do podpisywania PROSIGN.

    OpenEdge obsługuje teraz OAuth2 i SAML do uwierzytelniania i autoryzacji. Te standardowe protokoły zapewniają bezpieczny i wygodny mechanizm uwierzytelniania użytkowników bez udostępniania poufnych informacji. OpenEdge Authentication Gateway może automatycznie przekonwertować zweryfikowane tokeny na token OpenEdge Client Principal, który możemy obsługiwać w aplikacjach ABL.

    Administrowanie PASOE: do tej pory można było skonfigurować instancje tak aby w razie potrzeby agent wielosesyjny uruchamiał dodatkowe sesje, ale nie było możliwości aby te sesje były automatycznie przycinane. W obecnej wersji OpenEdge dodano nowe właściwości do pliku openedge.properties, które umożliwiają administratorowi systemu skonfigurowanie instancji PASOE tak, aby sesje ABL były przycinane gdy nie są już potrzebne czy też gdy osiągnęły limit czasu lub pamięci.

    W Developer Studio dodano ABL Type Hierarchy View, który pokazuje relacje rodzic-dziecko między klasami ABL i interfejsami, aby pomóc programiście ABL zobaczyć hierarchię i strukturę dziedziczenia klasy i przechodzenie do dowolnego elementu widocznego w widoku.

    Dla wykorzystujących AI Archiver do zapisu After Image pojawiła się ciekawa możliwość wystartowania tego procesu online bez konieczności wykonania backupu. Jest to szczególnie istotne dla dużych baz gdy wykonanie kopii powodowało wstrzymanie wykonywanie transakcji.

    W operacja przywracanie bazy PROREST dodano parametry do wykonania jej jako proces wielowątkowy.

    Jest jeszcze kilka nowinek po które odsyłam do dokumentacji.

    Profiler – narzędzie dewelopera cz. III

    Coraz więcej programistów korzysta z narzędzia Developer Studio, pora więc pokazać jak korzystać w nim z Profilera (dostępnego od wersji OE 11.6), omawianego w dwóch poprzednich artykułach.
    Środowisko tego narzędzia nadaje się o wiele bardziej do wyświetlania złożonych informacji w kilku okienkach niż tradycyjny edytor.
    Spróbujmy najpierw otworzyć wygenerowany wcześniej w profilerze plik typu .out. Najwygodniej będzie zmienić to rozszerzenie na natywne dla profilera czyli .prof.
    Importuję do nowego projektu OpenEdge plik .prof oraz dwa pliki procedur.

    Dwukrotne kliknięcie na plik .prof otwiera widok Profilera.

    Opis kolumn jest analogiczny jak opisany w poprzednim artykule, więc nie będę się powtarzać. Nas interesuje teraz jak generować plik .prof z poziomu Developer Studio po dokonaniu pewnych zmian w programie (np. chcę aby procedura orderval.p wykonała się dla wszystkich iteracji).
    Pierwszym krokiem jest dodanie katalogu profiler do ścieżki PROPATH dla projektu.
    Następnie, wybieramy z menu Run -> Run Configurations. Dodajemy nową konfigurację (np. o nazwie Profiler), wstawiamy nazwę procedury CustReport.p…

    … a w zakładce Profiler zaznaczamy pole Enable profiling.

    Klikamy przycisk Run i czekamy aż program zakończy działanie, po czym otwiera się okno Viewera z nowymi statystykami.

    Na razie kończę omawaiać to narzędzie. Niektórzy z Was chcieliby dowiedzieć się więcej o możliwości instalacji i wykorzystania OECC i temu poświęcę następne artykuły.

    Profiler – narzędzie dewelopera cz. II

    Dziś kontynuujemy wykorzystanie narzędzia Profiler Control do przetestowania kodu naszej aplikacji. Weźmy np. prosty poniższy przykład CustReport.p który wyświetla w pętli podstawowe pola z tablicy Customer,

    DEFINE VARIABLE dOrdervalue AS DECIMAL NO-UNDO.
    
    FOR EACH customer WHERE custnum < 100:
       dOrdervalue = 0.
       IF custnum < 40 THEN 
          RUN ordervalue.p (custnum, OUTPUT dOrdervalue).
       
       DISP custnum name dOrdervalue.
    
    END.
    

    a dla części iteracji uruchamia dodatkową procedurę ordervalue.p zliczającą sumę zamówień klienta.

    DEF INPUT PARAM icustnum AS INTEGER.
    DEF OUTPUT PARAM dordval AS DECIMAL.
    
    FIND customer WHERE customer.custnum = icustnum.
    
    FOR EACH order OF customer, EACH orderline OF order:
       dordval += price * qty.
    END.
    

    Po uruchomieniu Profilera zostanie wygenerowany plik typu .out. Jeśli spróbujemy go otworzyć przy pomocy przycisku VIEW z panelu narzędzia, dostaniemy komunikat o błędzie: Cannot load data. Don’t know how to load data for version 3.
    Otwórzmy plik zwykłym edytorem tekstowym, np. Notepad++. Na pierwszej pozycji znajduje się nr wersji a potem data. Zmieniamy wartość nr wersji 3 na 1.
    Zobaczmy przy okazji, że plik ten zawiera informacje generowane podczas inicjalizacji sesji oraz dane niezbędne do analizy przy pomocy Viewera.

    Po naciśnięciu VIEW zobaczymy poniższy ekran.

    Profiler udostępnia statystyki dotyczące działania programu. Dane te są podzielone według bloków i poszczególnych linii kodu. Każdy blok reprezentuje aktualną procedurę, procedurę wewnętrzną lub funkcję. W górnym pasku, po lewej stronie możemy wybrać zarejestrowaną sesję. Obszar 1 zawiera następujące informacje:

    Code Block: nazwa wewnętrznej procedury lub funkcji, tryger interfejsu użytkownika i nazwa programu
    Calls To: liczba wykonań tego bloku kodu
    Avg Time: średni czas w sekundach potrzebny do wykonania tego bloku kodu
    Tot Time: całkowity czas w sekundach potrzebny do wykonania tego bloku kodu
    %Session: procent całej sesji wykorzystany przez ten blok kodu w porównaniu z innymi blokami kodu
    Cum Time: całkowity czas potrzebny do wykonania tego bloku kodu oprócz całkowitego czasu wszystkich bloków kodu wywołanych przez ten blok.

    Obszar 3 zawiera informacje dot. linii kodu:

    Line: numer linii w wybranym programie
    Exec Count: liczba wykonań tej linii kodu
    Avg Exec: średni czas wykonania tej linii kodu w sekundach
    Tot Time: całkowity czas w sekundach potrzebny do wykonania tej linii kodu
    Cum Time: całkowity czas w sekundach, jaki zajęło wykonanie tego wiersza kodu, a także wszelkich bloków kodu, wywołanych przez tę linię. UWAGA: ta liczba będzie się różnić od Tot Time tylko wtedy, gdy linia kodu jest instrukcją uruchomienia procedury lub wywołania funkcji.
    Pozostałe pola nie są używane.

    Wreszcie obszar 2.
    Calling Code Block oraz Called Code Block umożliwiają nawigację między różnymi sekcjami kodu poprzez dwukrotne kliknięcie wybranego wiersza.
    Widzimy, że procedura ordervalue.p była wywołana 38 razy, co zajęło niecałe 4% czasu sesji.

    Jeszcze jedna sprawa – na ekranie wyjściowym Profilera (pierwszy obraz w poprzednim artykule) widzimy po prawej stronie trzy pola wyboru: Listing, Coverage, Tracking.
    Pierwsze służy do wygenerowania listingu, który będzie widoczny w Viewerze. Coverage służy do generowania dodatkowych danych dla procedur zewnętrznych, a Tracking do określenia filtra dla generowania danych tylko dla określonych procedur. Jeśli zaznaczymy Listing i ponownie uruchomimy sesję, na ekranie pojawi się listing programu, a wybór linii kodu a w browserze podświetli tę linię na listingu. Bardzo użyteczna funkcja.


    Teraz trzeba już tylko przetestować własne procedury aby zorientować się w przydatności Profilera.
    To jeszcze nie koniec. W następnym odcinku zobaczymy jak używać tego narzędzia w Developer Studio.

    Profiler – narzędzie dewelopera cz. I

    Profiler czy Profiler Control to narzędzie znane już od wersji V9 Progressa. Było dostępne w postaci źródłowej z katalogu DLC\src\samples\profile, a w późniejszych wersjach dodane do pakietu samples, który można pobrać oddzielnie. Jest to deweloperskie narzędzie darmowe i niewspierane. Wielu klientów korzysta z niego na całym świecie. Zostałem niedawno poproszony o przypomnienie jak rozpocząć z nim pracę, co opiszę w niniejszym artykule.

    Profiler jest powszechnym i użytecznym narzędziem programisty do oceny wydajności aplikacji. Krótko mówiąc, profiler dostarcza „profil” konkretnego wykonania programu czyli informacje o czasach wykonania poszczególnych modułów oraz kolejność ich wywołań; dzięki czemu można przeanalizować, gdzie program spędza większość czasu i jaka część aplikacji wywołuje inną część aplikacji. W szczególności możemy przeanalizować czas wykonań dla konkretnych zapytań lub znaleźć podejrzanie dużą liczbę iteracji dla instrukcji.

    Narzędzie to składa się z dwóch modułów – modułu zbierającego dane oraz modułu graficznego (Windows), w którym można te dane analizować. Profiler śledzi opóźnienia w aplikacji spowodowane przez kod programu ignorując jednocześnie te wywołane interakcją użytkownika.

    Pierwsza wersja tego narzędzia wymagała utworzenia pustej bazy prof.db i załadowania do niej definicji z pliku prof.df. Ja przedstawię tutaj nowszą wersję, w której baza nie jest potrzebna gdyż wszystkie dane są gromadzone w tablicach tymczasowych.
    Wersja ta zawiera graficzny interfejs użytkownika, który upraszcza uruchamianie i zatrzymywanie procedur. Może wykrywać czy jest uruchomiony Progress Dynamics a także umożliwia uruchamianie dynamicznych kontenerów oraz statycznych smart obiektów i innych procedur. Zawiera wszystkie te same informacje, ale eliminuje znaczną część złożoności poprzedniego narzędzia, eliminując czasochłonne ładowanie danych profilu. Do statystyk wykonania, dodano więcej informacji. To narzędzie zawiera również dodatkową funkcjonalność, która daje użytkownikowi możliwość wykonywania porównań i eksportowania danych do zewnętrznych programów. Można go pobrać tutaj.

    W niniejszym artykule oprócz wprowadzenia i informacji ogólnych znajdziecie metody jak rozpocząć z nim pracę. W styczniu natomiast napiszę jak interpretować dane.

    W zasadzie są dwie metody generowania danych dla profilera: uruchamiając narzędzie z parametrem startowym -profile lub używając handle (uchwyt) PROFILER. Najprostszym sposobem jest uruchomienie pliku profiler.w, co widać powyżej. Program ten uruchamiany jest bezparametrowo ale wykorzystuje on wspomniany uchwyt.
    Pojawi się komunikat czy uruchomić sesję profilera. Jeśli potwierdzicie, przełącznik radiowy ustawi się w pozycji Profile, jeśli nie, w pozycji Run.
    Wybieramy Profile i w polu Procedure wpisujemy nazwę profilowanej procedury (nie ma niestety drzewa systemu z plikami do wyboru). Oprócz pola procedury widać także pole Container. Jest ono aktywne gdy mamy otwartą sesję z produktem Progress Dynamics. Domyślnie narzędzie jest ustawione tak aby śledzić dane dla sesji klient-serwer lecz jest też możliwe śledzenie sesji dla klient-appserver dla Dynamics.

    Po wpisaniu nazwy programu i naciśnięciu Run, dane zostaną zapisane do pliku, którego nazwa jest generowana automatycznie (możemy ją oczywiście zmienić). W tym przypadku clntprof20221227.out. Po zakończeniu procesu wybierz przycisk Stop. Spowoduje to, że program profilujący zakończy działanie procedury (o ile nadal działa) a dane sesji zostaną wyeksportuje pliku wyjściowego (jeśli zaznaczone jest pole Write On Stop). Dane można także zapisać w dowolnym momencie naciskając przycisk Write Data.

    Możemy sami skorzystać z uchwytu PROFILER. Ta metoda jest wygodna jeśli chcemy programowo profilować tylko wybrane fragmenty kodu. Wymaga ona więcej pracy ale daje dodatkowe możliwości i w przypadku złożonych programów jest nieoceniona. Przykładowy fragment kodu widzimy poniżej.

    ASSIGN
       PROFILER:DESCRIPTION = "Profiler Start"
       PROFILER:DIRECTORY = "c:/WrkOpenEdge126/"
       PROFILER:FILE-NAME = "clntprof20221227.out"
       PROFILER:COVERAGE = TRUE
       PROFILER:LISTINGS = TRUE
       PROFILER:ENABLED = TRUE
       PROFILER:PROFILING = TRUE.
    

    Jeśli chcemy profilować dane całej aplikacji, możemy skorzystać z parametru startowego -profile profiler.txt który wstawiamy do ikonki lub skryptu uruchamiającego procedurę.

    W piku profiler.txt definiujemy parametry np:

       -description "Profiler Start"
       -listings = "c:/WrkOpenEdge126/"
       -filename = "clntprof20221227.out"
    

    OK, to na razie tyle. Następnym razem zajmiemy się generowaniem i analizą danych.

    OpenEdge 12.6

    Wersja OpenEdge 12.6 pojawiła się z końcem września br. jako Innovation Release (termin który zastąpił Non-LTS Release) Podczas instalacji trzeba jak zwykle podać ścieżkę do JDK – w tej wersji jest to JDK 17.
    Zaczynamy od nowości związanych z bazami danych.

    PROUTIL IDXCOMPACT – to popularne narzędzie poprawiające wydajność indexów także dla bazy online. Komenda ta została wzbogacona o opcję UNUSEDBLOCKS, użyteczną szczególnie po operacji usuwania dużej liczby rekordów. Powoduje ona skanowanie łańcucha “delete” i czyszczenia bloków indexowych w przypadku indexów unikalnych. Stosowanie dla indexów nie-unikalnych nie spowoduje ostrzeżenia ani błędu na konsoli.

    Z tą opcję nie można podać stopnia kompresji, gdyż spowoduje to ostrzeżenie i niewykonanie polecenia.

    Obcięcie obszaru przechowywania danych online.
    Do tej pory obcięcie obszaru (PROUTIL TRUNCATE AREA) można było wykonać jedynie dla zamkniętej bazy, po obcięciu pliku BI i wyłączeniu zapisu AI.
    Obecnie operację można przeprowadzić dla bazy włączonej. Obcięcie obszaru stosuje się po usunięciu dużej ilości danych, np. przeniesieniu danych historycznych do innego obszaru. Obcięcie obszaru można wykonać tylko gdy w obszarze nie znajdują się żadne obiekty (tablice, indexy, LOBy).

    Wprowadzono obsługę dużych plików dla licencji Workgroup, co ma zlikwidować problem gdy baza działająca w środowisku produkcyjnym Enterprise jest skopiowana do testowania i rozwoju, co często przeprowadza się w niższej licencji Workgroup. Od OE 12.6 znacznik obsługi dużych plików jest włączany automatycznie dla obu typów licencji.

    Usprawniony został mechanizm działania narzędzia do naprawy indexów PROUTIL IDXFIX. Dla opcji 1 i 8 skanowane są tylko te bloki obszaru typu II, które należą do podanych tabel i indexów. Usprawnienie nie działa dla bloków obszaru I. Poprawiono także mechanizm kasowania rekordów w tym samym narzędziu.

    Przejdźmy teraz do wybranych nowości deweloperskich.
    Identyfikacja Memory Leaks. Programiści mogą teraz używać klasy OpenEdge.Core.Util.LeakCheck w bibliotece corelib do przetwarzania logów i identyfikacji wycieków pamięci. Dokładne informacje o tej klasie można znaleźć w dokumentacji.
    Praktyczny opis identyfikacji wycieków pamięci znajduje się tutaj.

    Środowisko Progress Developer Studio dla OpenEdge zostało zaktualizowane i korzysta z wersji Eclipse 4.23.

    Został zoptymalizowany tutaj proces inicjalizacji widoczny szczególnie w przypadku złożonych i rozbudowanych workspace’ów.

    Warto dodać, że w tym samym czasie pojawiła się nowa wersja OE Command Center 1.2, w której administratorzy systemu mogą monitorować metryki wydajności PASOE oraz baz danych OE. Metryki wydajności są zbierane przy użyciu standardu OpenTelemetry (OTel).
    Zarządzanie PASOE zostało wzbogacone o funkcję klonowania instancji.
    Ponadto, został zautomatyzowany proces instalacji w systemie Windows, zamiast ręcznej edycji skryptów uruchamiany jest teraz instalator.
    O wielu innych nowościach możecie przeczytać w dokumentacji. Zapraszam do dyskusji na polskiej grupie PUG.

    Swagger UI i PASOE

    Swagger UI jest narzędziem które umożliwia wizualizację zasobów API bez konieczności implementacji dodatkowych zewnętrznych aplikacji.

    Swagger składa się z plików HTML, JavaScript i CSS, które dynamicznie generują dokumentację na podstawie interfejsu API.
    Jest dostępny w PASOE począwszy od wersji OE 12.0 (domyślnie wyłączony). Od wersji OE 12.2 jest domyślnie włączony dla instancji deweloperskich – należy pamiętać aby nigdy nie włączać go w środowiskach produkcyjnych.

    Dostęp do Swaggera jest z poziomu oemanagera (http://host:port/oemanager/), ale jeśli dostęp jest zabroniony, to wchodzimy z poziomu managera, czyli http://host:port/manager/, np. http://localhost:8813/manager.


    Tutaj klikając oemanager dostajemy ekran dokumentacji Swaggera.


    Ekran składa się z sekcji np. dla każdej warstwy transportowej,  Agent Manager, Session Manager i OEABL ManagerService.
    Przechodzimy do tej drugiej i klikamy na GET /applications, następnie Try it out i Execute.


    Dostajemy listę wszystkich aplikacji ABL dla instancji PASOE wraz z parametrami w postaci JSON. Listę tę można pobrać jako plik tekstowy.

    Jeśli w OEABL ManagerService kliknę GET /applications/{AppName}/webapps i wpiszę nazwę aplikacji ABL, dostanę w podobnej postaci listę wszystkich aplikacji webowych dla tejże aplikacji.

    Aby pobrać listę web servisów dla danej aplikacji webowej wybieram GET/applications/{AppName}/webapps/{WebAppName} i podaję nazwę aplikacji ABL i web serwisu.

    Jak widać na obrazkach czasowniki GET nie są jedynymi do użycia. Można np. zaktualizować listę poprzez czasownik POST czy zerować metryki (DELETE).
    Opcji jest bardzo wiele.

    1 2 3 5